f45ec8342715c18cc39aaffdb89d83862e3b7c42
[mw/milkymist.git] / cores / bt656cap / rtl / bt656cap_decoder.v
1 /*
2  * Milkymist VJ SoC
3  * Copyright (C) 2007, 2008, 2009, 2010 Sebastien Bourdeauducq
4  *
5  * This program is free software: you can redistribute it and/or modify
6  * it under the terms of the GNU General Public License as published by
7  * the Free Software Foundation, version 3 of the License.
8  *
9  * This program is distributed in the hope that it will be useful,
10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
12  * GNU General Public License for more details.
13  *
14  * You should have received a copy of the GNU General Public License
15  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
16  */
17
18 /*
19  * This module takes the BT.656 stream and puts out 32-bit
20  * chunks coded in YCbCr 4:2:2 that correspond to 2 pixels.
21  * Only pixels from the active video area are taken into account.
22  * The field signal indicates the current field used for interlacing.
23  * Transitions on this signal should be monitored to detect the start
24  * of frames.
25  * When the input signal is stable, this modules puts out no more
26  * than one chunk every 4 clocks.
27  */
28
29 module bt656cap_decoder(
30         input vid_clk,
31         input [7:0] p,
32
33         output reg stb,
34         output reg field,
35         output reg [31:0] ycc422
36 );
37
38 reg [7:0] ioreg;
39 always @(posedge vid_clk) ioreg <= p;
40
41 reg [1:0] byten;
42 reg [31:0] inreg;
43 always @(posedge vid_clk) begin
44         if(&ioreg) begin
45                 /* sync word */
46                 inreg[31:24] <= ioreg;
47                 byten <= 2'd1;
48         end else begin
49                 byten <= byten + 2'd1;
50                 case(byten)
51                         2'd0: inreg[31:24] <= ioreg;
52                         2'd1: inreg[23:16] <= ioreg;
53                         2'd2: inreg[15: 8] <= ioreg;
54                         2'd3: inreg[ 7: 0] <= ioreg;
55                 endcase
56         end
57 end
58
59 reg in_field;
60 reg in_hblank;
61 reg in_vblank;
62
63 always @(posedge vid_clk) begin
64         stb <= 1'b0;
65         if(byten == 2'd0) begin
66                 /* just transferred a new 32-bit word */
67                 if(inreg[31:8] == 24'hff0000) begin
68                         /*┬átiming code */
69                         in_hblank <= inreg[4];
70                         in_vblank <= inreg[5];
71                         in_field <= inreg[6];
72                 end else begin
73                         /*┬ádata */
74                         if(~in_hblank && ~in_vblank) begin
75                                 stb <= 1'b1;
76                                 field <= in_field;
77                                 ycc422 <= inreg;
78                         end
79                 end
80         end
81 end
82
83 endmodule